Hugo posting in Emacs

mike@puddingtime.org (mike) — Mon, 21 Apr 2025 08:37:39 -0700

I dug a bunch of stuff out of archived configs to get the Hugo blog going again, including my old ox-hugo setup.

ox-hugo lets you keep a monolithic org file where each post is an org heading:

** SyncTrain for Syncthing on iOS :syncthing:ios:iphone:
:PROPERTIES:
:EXPORT_FILE_NAME: 2025-04-20-synctrain-for-syncthing-on-ios
:EXPORT_HUGO_DATE: <2025-04-20>
:EXPORT_DATE: 2025-04-20
:EXPORT_HUGO_SECTION: blog
:EXPORT_HUGO_CUSTOM_FRONT_MATTER+: :cover '((image ."" ) (caption . "" ))
:EXPORT_HUGO_CUSTOM_FRONT_MATTER+: :images '(/mph-logo.png)
:EXPORT_DESCRIPTION:
:END:

A few years ago I gave Mobius Sync a try as a Syncthing client on my iPhone and iPad. That went about as well as you'd expect for an iOS adaptation of something that wants to be an always-on filesystem-watching daemon. It wasn't really worth the stress of wondering what quantum state of sync everything is in, and I hated having to explicitly open it up to nudge it to sync.

If a heading is marked as TODO, that translates to “draft” for Hugo. If you use org tags in the heading :tag1:tag2: those become post tags.

If you set up org-capture and a few hooks correctly, it takes a lot of friction away by exporting the Markdown files when you save the file.

Something has changed since I was last using it regularly, and some bugs crept into my setup. I was willing to live with a few of them, but last night I came across some goofy thing where Hugo’s Markdown renderer (goldmark) and ox-hugo were interacting strangely, and the org-to-markdown conversion was indenting unordered lists enough that goldmark picked them up as indented code blocks. I did some poking around and saw that a lot of people have been vexed by that: goldmark uses the CommonMark specification, which includes indented code blocks, and goldmark offers no toggle for it as a workaround.

How many seconds do we have of this precious life?

I do like working out of Emacs and not switching around to do stuff, so I found an old Ruby script I wrote to make generating a Hugo post with all the stuff particular to my setup and worked with a co-pilot to convert it to a lisp package.

When you invoke hpost-new it prompts for whether to follow the “daily” or regular post style, then asks for title, tags, and description, then plops the new file into the right place and opens it for editing.

This goes in ~/.config/doom/lisp:

;;; hpost.el --- Create new Hugo posts from Emacs  -*- lexical-binding: t; -*-

;; Adjust this to point at your Hugo or ox‑hugo content directory.
(defcustom hpost-posts-dir "~/blog/content/posts/"
  "Directory where new Hugo posts are written."
  :type 'directory :group 'hpost)

(defun hpost--slugify (title)
  "Convert TITLE to a URL‑friendly slug."
  (let* ((s (downcase title))
         (s (replace-regexp-in-string "[^a-z0-9]+" "-" s))
         (s (replace-regexp-in-string "^-\|-$" "" s)))
    (truncate-string-to-width s 60 nil nil ""))) ; hard cap at 60 chars

(defun hpost--today () (format-time-string "%Y-%m-%d"))
(defun hpost--now   () (format-time-string "%Y-%m-%dT%H:%M:%S%z"))

;;;###autoload
(defun hpost-new (title tags summary &optional daily)
  "Create a new Hugo post.

Interactively prompts for TITLE, TAGS (comma‑delimited), and SUMMARY.
With prefix arg, treat it as a daily note (pre‑sets title and tags)."
  (interactive
   (let* ((daily (y-or-n-p "Daily note? "))
          (title (if daily
                     (format "Daily notes for %s" (hpost--today))
                   (read-string "Title: ")))
          (tags  (if daily "journal"
                   (read-string "Tags (comma): ")))
          (summary (read-string "Summary: ")))
     (list title tags summary daily)))
  (let* ((slug    (if daily "daily-notes" (hpost--slugify title)))
         (fname   (concat (hpost--today) "-" slug ".md"))
         (path    (expand-file-name fname hpost-posts-dir)))
    (when (file-exists-p path)
      (user-error "File %s already exists" fname))
    (with-temp-buffer
      (insert (format
"---
title: \"%s\"
date: %s
draft: true
tags:%s
summary: \"%s\"
---

" title (hpost--now)
        (mapconcat (lambda (t) (format "\n- %s" (string-trim t)))
                   (split-string tags ",") "")
        summary))
      (write-region (point-min) (point-max) path))
    (find-file path)
    (message "New post created: %s" path)))

(provide 'hpost)
;;; hpost.el ends here

… and the config:

;; --- Hugo post helper ---------------------------------------
(use-package! hpost
  :load-path "lisp/"
  :defer t
  :custom
  (hpost-posts-dir "~/blog/content/posts/")
  :config
  ;; Optional keybinding:   n h
  (map! :leader
        (:prefix ("n" . "notes")
         :desc "New Hugo post" "h" #'hpost-new)))

It goes well with a few helpers I made to fire up or shut down the Hugo preview server within Emacs:

(defun my-start-hugo-server ()
  "Run Hugo server with live reloading."
  (interactive)
  (let* ((root (projectile-project-root))
         (default-directory root))
    (compile "hugo server -D --navigateToChanged" t)))

(defun my-stop-hugo-server ()
  "Stop Hugo server."
  (interactive)
    (kill-compilation))

(map! :leader
      (:prefix ("H" . "Hugo")
       :desc "Start Hugo Server" "S" #'my-start-hugo-server
       :desc "Stop Hugo Server" "s" #'my-stop-hugo-server))

So, SPC H S to start the test server, and SPC n h to start a new post. When I save the buffer, the preview server jumps to the newly written page in the browser.

hi, it's mike

Hugo posting in Emacs